COBOL utilise les numéros de niveau 01 à 49 pour définir une structure de données dans une hiérarchie de parties constitutives – plus le numéro de niveau est élevé, plus l’élément est bas dans la hiérarchie.

Les numéros eux-mêmes n’ont généralement pas de signification particulière, mais la relation entre les numéros de niveau identifie les niveaux au sein de la hiérarchie.

Cependant, lors du codage des zones de données à utiliser avec SQL, le niveau numéro 49 a une signification particulière.
49 est utilisé pour déclarer des identifiants d’éléments élémentaires de longueur variable – généralement des variables VARCHAR, LONG VARCHAR, VARGRAPHIC et LONG VARGRAPHIC.

Lorsque le niveau 49 est utilisé, le groupe contient un champ Longueur de 2 octets suivi du nom réel du champ (défini comme PIC X(##) avec ## étant la longueur maximale).
Les données du champ varient en longueur et lorsque les données sont placées dans le champ, seul le nombre de caractères défini dans l’élément de longueur est renvoyé, sans caractères de remplissage.

Cela peut causer un problème car les informations précédentes stockées dans ce champ ne sont pas automatiquement effacées et la valeur précédente était plus longue que la valeur actuelle.
Lorsque les données sont récupérées, la longueur et l’élément de données sont renseignés.

Une longueur de 0 indique que la colonne n’est pas remplie.

Voici un exemple d’utilisation du Level 49 :

----+---10----+---20----+---30----+---40----+---50----+ 

       01 NOM-COLONNE. 
           49 COLONNE-NOM-LEN PIC S9(04) USAGE COMP. 
           49 COLONNE-NOM-DONNEES PIC X(273).

Voici une explication de cette disposition :

• NOM-COLONNE est le nom de la colonne SQL
• COLONNE-NOM-LEN est un champ entier de 1 à 4 qui contient la longueur des données dans NOM-COLONNE.
• COLONNE-NOM-DONNEES contient les données réelles et la clause PIC indique la plus grande valeur de variable pouvant être affectée à cette variable.

Exemple DCLGEN avec niveau 49

****************************************************************** 
* DCLGEN TABLE(MYTABLE)                                          * 
*        LIBRARY('prefix.SRCLIB.DATA(MYTABLE))                   * 
*        LANGUAGE(COBOL)                                         * 
*        APOST                                                   * 
*        DCLBIT(YES)                                             * 
* ... IS THE DCLGEN COMMAND THAT MADE THE FOLLOWING STATEMENTS   * 
****************************************************************** 
     EXEC SQL DECLARE MYTABLE TABLE                                
     ( COL1                           CHAR(10) NOT NULL,           
       COL2                           CHAR(10),                    
       COL3                           VARCHAR(12) NOT NULL,        
       COL4                           VARCHAR(12) NOT NULL         
     ) END-EXEC.                                                   
****************************************************************** 
* DECLARED VARIABLES FOR 'FOR BIT DATA' COLUMNS                  * 
****************************************************************** 
     EXEC SQL DECLARE                                              
      :COL3                                                        
     ,:COL4                                                        
     VARIABLE FOR BIT DATA END-EXEC.                               
****************************************************************** 
* COBOL DECLARATION FOR TABLE MYTABLE                            * 
****************************************************************** 
 01  DCLMYTABLE.                                                   
     10 COL1                 PIC X(10).                            
     10 COL2                 PIC X(10).                            
     10 COL3.                                                      
        49 COL3-LEN          PIC S9(4) USAGE COMP.                 
        49 COL3-TEXT         PIC X(12).                            
     10 COL4.                                                      
        49 COL4-LEN          PIC S9(4) USAGE COMP.                 
        49 COL4-TEXT         PIC X(12).                            
****************************************************************** 
* LE NOMBRE DE COLONNES DÉCRIT PAR CETTE DÉCLARATION EST DE 4     * 
******************************************************************

Le niveau 66 est utilisé pour renommer d’autres variables de programme.

IDENTIFICATION DIVISION.
PROGRAM-ID.  NIVEAU66.
AUTHOR.      LA COMMUNAUTE DU COBOL.

* Un exemple de programme qui démontre l'utilisation du niveau 66

DATA DIVISION.
WORKING-STORAGE SECTION.

* Ainsi, en accédant à la variable MOIS-JOUR-SYSTEME,
* nous verrons le contenu des variables MOIS-SYSTEME et JOUR-SYSTEME.

01  DATE-SYSTEME.
    05  ANNEE-SYSTEME       PIC 9(004) VALUE ZEROES.
    05  MOIS-SYSTEME        PIC 9(002) VALUE ZEROES.
    05  JOUR-SYSTEME        PIC 9(002) VALUE ZEROES.
66  MOIS-JOUR-SYSTEME       RENAMES MOIS-SYSTEME THRU JOUR-SYSTEME.


* Niveau 66 - RENAMES (joint des champs contigus)

01  REGISTRE.
    05 RUE                 PIC X(030).
    05 NUM                 PIC 9(005).
    05 APPART              PIC 9(004).
    05 QUARTIER            PIC X(015).
    05 VILLE               PIC X(025).
    05 ETAT                PIC X(002).
    05 CP                  PIC 9(005).
66  ADRESSE                RENAMES RUE      THRU APPART.
66  VILLE-ETAT             RENAMES VILLE    THRU ETAT.
66  QUARTIER-VILLE         RENAMES QUARTIER THRU VILLE.
66  NUMERO                 RENAMES NUM.
66  IND-COMPLET            RENAMES RUE      THRU CP.
66  FIN-PRESQUE            RENAMES ADRESSE THRU VILLE-ETAT.


PROCEDURE DIVISION.

001-INIT.

    MOVE 20201025               TO DATE-SYSTEME  
    DISPLAY "DATE-SYSTEME     : "  DATE-SYSTEME 
    DISPLAY "ANNEE-SYSTEME    : "  ANNEE-SYSTEME 
    DISPLAY "MOIS-SYSTEME     : "  MOIS-SYSTEME 
    DISPLAY "JOUR-SYSTEME     : "  JOUR-SYSTEME 
    DISPLAY "MOIS-JOUR-SYSTEME: "  MOIS-JOUR-SYSTEME 

* Resultat do test :

* DATE-SYSTEME     : 20201025
* ANNEE-SYSTEME    : 2020
* MOIS-SYSTEME     : 10
* JOUR-SYSTEME     : 25
* MOIS-JOUR-SYSTEME: 1025

    MOVE "AVENUE DES CHAMPS-ELYSEES" TO RUE
    MOVE 00037                   TO NUM 
    MOVE 101                     TO APPART
    MOVE "PARIS 8"               TO QUARTIER
    MOVE "PARIS"                 TO VILLE
    MOVE "FR"                    TO ETAT
    MOVE 75008                   TO CP

    DISPLAY "ADRESSE        : "  ADRESSE               
    DISPLAY "VILLE-ETAT     : "  VILLE-ETAT          
    DISPLAY "QUARTIER-VILLE : "  QUARTIER-VILLE          
    DISPLAY "NUMERO         : "  NUMERO                 
    DISPLAY "IND-COMPLET    : "  IND-COMPLET           
    DISPLAY "END-PRESQUE    : "  END-PRESQUE              

* Resultat de test:

* ADRESSE        : AVENUE DES CHAMPS-ELYSEES     000370101
* VILLE-ETAT     : PARIS                    FR
* QUARTIER-VILLE : PARIS 8        PARIS                 
* NUMERO         : 00037
* IND-COMPLET    : AVENUE DES CHAMPS-ELYSEES     000370101PARIS 8        PARIS                 FR75008
* END-PRESQUE    : AVENUE DES CHAMPS-ELYSEES     000370101PARIS                 FR

    STOP RUN.

Le niveau 77 identifie les entrées de description d’éléments de données qui sont des éléments indépendants WORKING-STORAGE, LOCAL-STORAGE ou LINKAGE SECTION.

Ils ne sont pas des subdivisions d’autres éléments et ne sont pas subdivisés.

Les éléments de niveau 77 doivent commencer dans la zone A.

77  PRECEDENT               PIC S9(04) VALUE -1.
77  ACTUELLE                PIC S9(04) VALUE  1.
77  SUIVANTE                PIC S9(04).

Un élément de niveau 88 est utilisé pour nommer une condition.

L’utilisation d’un nom de condition présente deux avantages principaux :

• Il permet d’attribuer un nom descriptif à ce qui pourrait autrement ne pas être une raison évidente pour un test.
  
• Si une condition est sujette à changement en raison d’une condition indépendante de la volonté du développeur et que cette condition est testée à plusieurs endroits dans la PROCEDURE DIVISION, l’utilisation du nom de la condition dans la division au lieu de la condition réelle permet au programmeur qui maintient le programme de modifier les valeurs. ​​qui définissent la condition à un seul endroit dans la DATA DIVISION, plutôt que d’avoir à rechercher toutes les occurrences individuelles dans la PROCEDURE DIVISION.

Exemple

       05  WS-COMPANY         PIC 9(004).
           88  WS-PARIS       VALUES  3
                                     15
                                     39 THRU 42
                                     76.

       Pour tester une entreprise faisant des affaires à 
       Paris, sans les niveaux item 88, 
	   il faudrait coder : 

      * IF condition simple : 

           IF  WS-COMPANY EQUAL  3 OR 15 OR 39 OR
                                40 OR 41 OR 42 OR 76

      * IF avec condition de niveau 88 :

           IF  WS-PARIS 
               description de la condition 
           END-IF

Il ne serait pas évident pour la personne lisant le code quelle condition vous testiez.
Avec le 88 en place, vous pouvez coder le test comme ceci :

Toute personne lisant le code pourrait dire quelle condition vous testiez, et si la vérification a été effectuée plusieurs fois dans la PROCEDURE DIVISION et que la liste des entreprises faisant des affaires en Californie change, il vous suffit de modifier la liste des valeurs associées à 88 – élément de niveau.

Alors que le nom de données associé à un élément de niveau 88 peut avoir n’importe quelle valeur, l’élément de niveau 88 lui-même ne peut avoir qu’une seule des deux valeurs, vrai ou faux.
L’élément est vrai si l’élément de données immédiatement supérieur à 88 a l’une des valeurs associées à l’élément 88, sinon il est faux.

Les objets de niveau 88 peuvent être associés à des objets de groupe ou élémentaires.

IDENTIFICATION DIVISION.
PROGRAM-ID.  NIVEAU88.
AUTHOR.      LA COMMUNAUTE DU COBOL.

* Un exemple de programme qui démontre l'utilisation du niveau 88 
* Le verbe EVALUATE est utilisé. 

DATA DIVISION.
WORKING-STORAGE SECTION.

01  OPTION               PIC X(001).
    88 VOYELLE          VALUE "a", "e", "i", "o", "u"
                              "A", "E", "I", "O", "U".

    88 CONSONNE         VALUE "b", "c", "d", "f", "g", "h"
                              "j" THRU "n", "p" THRU "t", "v" THRU "z"
                              "B", "C", "D", "F", "F", "H"
                              "J" THRU "N", "P" THRU "T", "V" THRU "Z".

    88 NUMERO           VALUE "0" THRU "9".

    88 CARACTERE-VALIDE VALUE "a" THRU "z", "A" THRU "Z"
                              "0" THRU "9".

PROCEDURE DIVISION.

001-INIT.

    DISPLAY "Saisir un caractère ou un chiffre.".

    ACCEPT OPTION.

    EVALUATE TRUE
        WHEN VOYELLE   DISPLAY "OPTION " OPTION " est une VOYELLE."
        WHEN CONSONNE  DISPLAY "OPTION " OPTION " est une CONSONNE."
        WHEN NUMERO    DISPLAY "OPTION " OPTION " est un NUMERO."
        WHEN OTHER     DISPLAY  OPTION " OPTION INVALIDE"
    END-EVALUATE

    STOP RUN.