Cette section (SCREEN SECTION) sert (selon la version du compilateur utilisé) à créer un dessin d’écran.

Sa forme générale est :

nombre niveau nom-écran AUTO SECURE REQUIRED FULL.

Le nombre niveau doit être un entier compris entre 01 et 49.

Le format au niveau d’un écran élémentaire est :

Nombre-niveau

BLANK SCREEN                          vide l'écran
LINE NUMBER IS entier-1
COLUMN NUMBER IS entier-2
BELL                                  sonnerie
UNDERLINE
REVERSE-VIDEO
HIGHLIGHT
FOREGROUND-COLOR entier-3
BACKGROUND-COLOR entier-4
VALUE is litéral                      affiche le litéral
PIC IS description
      FROM            |
      TO              |               Identifier
      USING           |
JUSTIFIED
AUTO
SECURE
REQUIRED
FULL.

Remarques:

La longueur maximum pour un élément de l’écran est de 80 caractères.

AUTO : passe automatiquement au champs suivant lorsque celui en cours est rempli.

SECURE : met des * dans le champs lors de l’encodage, c’est une sécurité pour le mot de passe.

REQUIRED : une réponse non vide est exigée.

FULL : la zone doit être remplie pour la lecture, son usage permet l’utilisation des tabulations.

PICTURE : oblige l’usage d’un USING, TO ou FROM.

BLANK SCREEN : met tout l’écran à blanc et le curseur est mis en position 1.

Les codes couleurs sont :
– 0 : noir
– 1 : bleu
– 2 : vert
– 3 : cyan
– 4 : rouge
– 5 : magenta
– 6 : brun
– 7 : blanc
– 8 : gris
– 9 : bleu clair
– 10 : vert clair

VALUE is litéral spécifie une chaîne de caractères qui doit être écrite lors du DISPLAY de cet écran. Ce litéral doit être entre quotes et n’est pas imprimé lors d’un ACCEPT de l’écran.
VALUE est incompatible avec PICTURE.

PICTURE spécifie le format de présentation de la donnée. Durant un DISPLAY le contenu du FROM ou du USING est transféré dans une variable temporaire. (JAMAIS DE VARIABLES INDICEES)

LINE et COLUMN donnent la position du curseur.

FOREGROUND et BACKGROUND-COLOR donnent la couleur des caractères et du fond.

Exemple :

SCREEN SECTION.
01 ECRAN1.
   02 BLANK SCREEN BACKGROUND-COLOR 1.
   02 LINE 5 COL 15 PIC X(10) TO PSW SECURE BELL AUTO.
   02 LINE 10 COL 10 VALUE "VOTRE MOT DE PASSE".
   02 LINE 15 COL 20 PIC X(25) TO NOM.
   02 LINE 20 COL 11 VALUE "VOTRE NOM".

PROCEDURE DIVISION.
DEBUT.
    DISPLAY ECRAN1.
    ACCEPT ECRAN1.

Pour envoyer une image écran on utilise le DISPLAY, pour prendre les informations encodées sur l’écran on utilise l’ACCEPT.

Affichage     : DISPLAY
Saisie             : ACCEPT
FROM           : On affiche à partir d ’une zone de données.
TO                   : On reçoit pour une zone de données.
USING          : On affiche et reçoit en utilisant une zone de données

IDENTIFICATION DIVISION.
PROGRAM-ID. Program1.
AUTHOR. jean-marie meskens.
DATE-WRITTEN. vendredi 1 septembre 2006 8:18:52.
REMARKS.

ENVIRONMENT DIVISION.
CONFIGURATION SECTION.
SPECIAL-NAMES.

  DECIMAL-POINT IS COMMA.

INPUT-OUTPUT SECTION.
FILE-CONTROL.

DATA DIVISION.
WORKING-STORAGE SECTION.
77 ch1       PIC 99.
77 ch2       PIC 99.
77 somme     PIC 999.
SCREEN SECTION.
01 ecran-entree.
  05 BLANK SCREEN.
  05 LINE-1.
    10 LINE 1 COLUMN 10 VALUE 'Entrez un chiffre : '.
    10 LINE 1 COLUMN 40 PIC 99 TO ch1.
  05 LINE-2.
    10 LINE 2 COLUMN 10 VALUE 'Un autre chiffre SVP : '.
    10 LINE 2 COLUMN 40 PIC 99 TO ch2.
01 ecran-sortie.
  05 LINE-4.
    10 LINE 4 COLUMN 10 VALUE 'Voici la somme : '.
    10 LINE 4 COLUMN 40 PIC ZZZ using somme.
PROCEDURE DIVISION.
DEB.
   MOVE ZEROS TO ch1, ch2, somme.
   DISPLAY ecran-entree.
   ACCEPT ecran-entree.
   ADD ch1 to ch2 GIVING somme.
   DISPLAY ecran-sortie.
   accept Ecran-Sortie.
   STOP RUN.